Belajar Membuat Program Dengan Excel VBA- Pelajaran 4 : Membuat Program Userform

Bab ini mengajarkan Anda bagaimana untuk membuat Excel VBA UserForm. UserForm akan dibuat terlihat sebagai berikut:

Add the Controls

Untuk menambahkan kontrol ke UserForm, jalankan langkah-langkah berikut.

1. Buka Visual Basic Editor. Jika Project Explorer tidak terlihat, klik View, Project Explorer.

2. Klik Insert, UserForm. Jika Toolbox tidak muncul secara otomatis, klik View, Toolbox. Layar Anda harus terlihat sebagai berikut.

3. Tambahkan kontrol yang tercantum dalam tabel di bawah ini. Setelah ini telah selesai, hasilnya harus konsisten dengan gambar UserForm ditampilkan sebelumnya. Misalnya, membuat teks kotak kontrol dengan mengklik TextBox dari Toolbox. Berikutnya, Anda dapat drag teks box pada UserForm. Ketika Anda tiba di Car frame, ingatlah untuk menggambar frame ini terlebih dahulu sebelum Anda menempatkan dua option buttons di dalamnya.

4. Ubah names dan captions dari controls sesuai dengan tabel di bawah. Nama yang digunakan dalam kode VBA Excel. Captions yaitu yang muncul di layar Anda. Ini adalah praktik yang baik untuk mengubah nama kontrol. Ini akan membuat kode Anda lebih mudah dibaca. Untuk mengubah name dan captions dari kontrol, klik View, Properties Window dan klik pada setiap kontrol.

Control	Name	Caption
Userform	DinnerPlannerUserForm	Dinner Planner
Text Box	NameTextBox
Text Box	PhoneTextBox
List Box	CityListBox
Combo Box	DinnerComboBox
Check Box	DateCheckBox1	June 13th
Check Box	DateCheckBox2	June 20th
Check Box	DateCheckBox3	June 27th
Frame	CarFrame	Car
Option Button	CarOptionButton1	Yes
Option Button	CarOptionButton2	No
Text Box	MoneyTextBox
Spin Button	MoneySpinButton
Command Button	OKButton	OK
Command Button	ClearButton	Clear
Command Button	CancelButton	Cancel
7 Labels	No need to change	Name:, Phone Number:, etc.

Catatan: combo box adalah daftar drop-down di mana pengguna dapat memilih item atau mengisi / pilihannya sendiri. Hanya salah satu option buttons dapat dipilih.

Show the Userform

Untuk menampilkan UserForm, menempatkan tombol perintah pada lembar kerja Anda dan tambahkan baris kode berikut:

Private Sub CommandButton1_Click()

DinnerPlannerUserForm.Show

End Sub

Kita sekarang akan membuat Sub UserForm_Initialize. Bila Anda menggunakan Show metode untuk UserForm, sub ini secara otomatis akan dieksekusi.

1. Buka Visual Basic Editor.

2. Dalam Project Explorer, klik kanan pada DinnerPlannerUserForm dan kemudian klik View Code.

3. Pilih UserForm dari list drop-down kiri. Pilih Inisialisasi dari daftar drop-down yang tepat.

4. Tambahkan baris kode berikut:

Private Sub UserForm_Initialize()

'Empty NameTextBox
NameTextBox.Value = ""

'Empty PhoneTextBox
PhoneTextBox.Value = ""

'Empty CityListBox
CityListBox.Clear

'Fill CityListBox
With CityListBox
    .AddItem "San Francisco"
    .AddItem "Oakland"
    .AddItem "Richmond"
End With

'Empty DinnerComboBox
DinnerComboBox.Clear

'Fill DinnerComboBox
With DinnerComboBox
    .AddItem "Italian"
    .AddItem "Chinese"
    .AddItem "Frites and Meat"
End With

'Uncheck DataCheckBoxes
DateCheckBox1.Value = False
DateCheckBox2.Value = False
DateCheckBox3.Value = False

'Set no car as default
CarOptionButton2.Value = True

'Empty MoneyTextBox
MoneyTextBox.Value = ""

'Set Focus on NameTextBox
NameTextBox.SetFocus

End Sub

Penjelasan: text boxes dikosongkan, list boxes dan combo boxes diisi, check boxes yang dicentang, dll

Assign the Macros

Kami sekarang telah menciptakan bagian pertama dari UserForm. Meskipun terlihat sudah rapi, namun ketika kita klik tombol perintah pada UserForm, program belum bisa jalan.

1. Buka Visual Basic Editor.

2. Dalam Project Explorer, double klik kali pada DinnerPlannerUserForm.

3. Double klik pada tombol Money spin.

4. Tambahkan baris kode berikut:

Private Sub MoneySpinButton_Change()

MoneyTextBox.Text = MoneySpinButton.Value

End Sub

Penjelasan: baris kode ini update  text box saat Anda menggunakan tombol spin.


5. Double klik pada tombol OK.

6. Tambahkan baris kode berikut:

Private Sub OKButton_Click()

Dim emptyRow As Long

'Make Sheet1 active
Sheet1.Activate

'Determine emptyRow
emptyRow = WorksheetFunction.CountA(Range("A:A")) + 1

'Transfer information
Cells(emptyRow, 1).Value = NameTextBox.Value
Cells(emptyRow, 2).Value = PhoneTextBox.Value
Cells(emptyRow, 3).Value = CityListBox.Value
Cells(emptyRow, 4).Value = DinnerComboBox.Value

If DateCheckBox1.Value = True Then Cells(emptyRow, 5).Value = DateCheckBox1.Caption

If DateCheckBox2.Value = True Then Cells(emptyRow, 5).Value = Cells(emptyRow, 5).Value & " " & DateCheckBox2.Caption

If DateCheckBox3.Value = True Then Cells(emptyRow, 5).Value = Cells(emptyRow, 5).Value & " " & DateCheckBox3.Caption

If CarOptionButton1.Value = True Then
    Cells(emptyRow, 6).Value = "Yes"
Else
    Cells(emptyRow, 6).Value = "No"
End If

Cells(emptyRow, 7).Value = MoneyTextBox.Value

End Sub

Penjelasan: pertama, kita mengaktifkan Sheet1. Berikutnya, kita menentukan emptyRow. Variabel emptyRow adalah baris pertama yang kosong dan menambahkan setiap kali sebuah record ditambahkan. Akhirnya, kita mentransfer informasi dari UserForm ke kolom tertentu dari emptyRow.

7. Double klik pada tombol Clear.

8. Tambahkan baris kode berikut:Penjelasan: baris kode ini menut

Private Sub ClearButton_Click()

Call UserForm_Initialize

End Sub

Penjelasan: baris kode ini memanggil Sub UserForm_Initialize ketika Anda klik pada tombol Clear.

9. Klik dua kali pada Batal Button.

10. Tambahkan baris kode berikut:

Private Sub CancelButton_Click()

Unload Me

End Sub

UserForm keluar ketika Anda klik pada tombol Cancel.

Test the Userform

Keluar dari Visual Basic Editor, masukkan label yang ditunjukkan di bawah ke baris 1 dan menguji UserForm.

hasil:

Sumber: excel-easy.com

Read More

Belajar Membuat Program Dengan Excel VBA- Pelajaran 3 : If Then Statement & Loop

If Then Statement

Tempatkan command button pada worksheet Anda dan tambahkan baris kode berikut:

Dim score As Integer, result As String
score = Range("A1").Value

If score >= 60 Then result = "pass"

Range("B1").Value = result

Penjelasan: jika score lebih besar dari atau sama dengan 60, Excel VBA kembali lulus.

Terjadi ketika Anda mengklik command button pada lembar kerja:

Catatan: jika skor kurang dari 60, Excel VBA menampilkan hasil variabel kosong ke sel B1.

Else Statement

Tempatkan command button pada worksheet Anda dan tambahkan baris kode berikut:

Dim score As Integer, result As String
score = Range("A1").Value

If score >= 60 Then
    result = "pass"
Else
    result = "fail"
End If

Range("B1").Value = result

Penjelasan: jika skor lebih besar dari atau sama dengan 60, Excel VBA kembali lulus, kebalikan hasil Excel VBA gagal.

Hasilnya ketika Anda mengklik command button pada lembar kerja:

Loop

1. Single Loop

Anda dapat menggunakan satu loop untuk loop melalui berbagai satu dimensi dari cell.

Tempatkan command button pada lembar kerja Anda dan tambahkan baris kode berikut:

Dim i As Integer

For i = 1 To 6
    Cells(i, 1).Value = 100
Next i

Hasilnya:

2. Double Loop

Anda dapat menggunakan loop ganda untuk loop dengan dua dimensi cells.

Tempatkan command button pada lembar kerja Anda dan tambahkan baris kode berikut:

Dim i As Integer, j As Integer

For i = 1 To 6
    For j = 1 To 2
        Cells(i, j).Value = 100
    Next j
Next i

Hasilnya:

3. Triple Loop

Anda dapat menggunakan loop tiga untuk loop melalui rentang dua dimensi pada beberapa lembar kerja Excel.

Tempatkan command button pada lembar kerja Anda dan tambahkan baris kode

Dim c As Integer, i As Integer, j As Integer

For c = 1 To 3
    For i = 1 To 6
        For j = 1 To 2
            Worksheets(c).Cells(i, j).Value = 100
        Next j
    Next i
Next c

4. Do While Loop

Selain For Next loop, ada loop lain di Excel VBA. Misalnya, Do While Loop. Kode ditempatkan di antara Do While dan Loop akan diulang selama bagian setelah Do While benar.

1. Tempatkan command button pada lembar kerja Anda dan tambahkan baris kode berikut:

Dim i As Integer
i = 1

Do While i < 6
    Cells(i, 1).Value = 20
    i = i + 1
Loop

Hasilnya:

2. Masukkan beberapa nomor di kolom A.

3. Tempatkan command button pada lembar kerja Anda dan tambahkan baris kode berikut:

Dim i As Integer
i = 1

Do While Cells(i, 1).Value <> ""
    Cells(i, 2).Value = Cells(i, 1).Value + 10
    i = i + 1
Loop

Hasilnya:

Sumber: excel-easy.com

Read More

Belajar Membuat Program Dengan Excel VBA- Pelajaran 2 : MsgBox & Workbook and Worksheet Object

MsgBox

MsgBox adalah kotak dialog di Excel VBA dapat Anda gunakan untuk menginformasikan pengguna program Anda. Tempatkan command button pada lembar kerja Anda dan tambahkan baris kode berikut:

1. Pesan sederhana.

 MsgBox "This is fun"                                                           

Hasilnya ketika Anda mengklik command button pada lembar:

2. Sebuah pesan tampil. Pertama, masukkan nomor ke sel A1 pada lembar kerja Anda.

 MsgBox "Entered value is " & Range("A1").Value                                  

Hasilnya ketika Anda mengklik command button pada sheet:

Catatan: kami menggunakan & operator untuk menggabungkan (bergabung) dua string. Meskipun Range ("A1"). Value tidak string, program akan tetap berjalan.

3. Untuk memulai baris baru dalam pesan, menggunakan vbNewLine.

 MsgBox "Line 1" & vbNewLine & "Line 2"                                          

Hasilnya ketika Anda mengklik command button pada lembar:

Workbook and Worksheet Object

Pelajari lebih lanjut tentang Workbook dan Worksheet objek di Excel VBA.

obyek Hirarki

Dalam Excel VBA, sebuah objek dapat berisi objek lain, dan objek yang dapat berisi objek lain, dll Dengan kata lain, pemrograman Excel VBA melibatkan bekerja dengan hirarki objek. Ini mungkin terdengar cukup membingungkan, tapi kami akan membuat jelas.

Ibu dari semua objek adalah Excel itu sendiri. Kami menyebutnya objek aplikasi. Objek aplikasi berisi objek lainnya. Sebagai contoh, objek Workbook (file Excel). Ini dapat berupa workbook yang telah Anda buat. Objek Workbook berisi objek-objek lain, seperti objek Worksheet. Objek Worksheet berisi objek-objek lain.

Buat bab Makro menggambarkan bagaimana menjalankan kode dengan mengklik command button. Kami menggunakan baris kode berikut:

 Range("A1").Value = "Hello"                                                                 

tapi apa yang kita maksudkan adalah:

 Application.Workbooks("create-a-macro").Worksheets(1).Range("A1").Value = "Hello"           

Catatan: objek yang terhubung dengan titik. Untungnya, kita tidak perlu menambahkan baris kode dengan cara ini. Itu karena kami menempatkan command button di create-a-macro.xls, pada lembar kerja pertama. Sadarilah bahwa jika Anda ingin mengubah hal-hal di lembar kerja yang berbeda, Anda harus menyertakan objek Worksheet. Baca terus.

Collections

Anda mungkin telah memperhatikan bahwa Workbooks dan Worksheets keduanya jamak. Itu karena mereka collections. Workbooks collection berisi semua objek Workbook yang sedang terbuka. Worksheets collection berisi semua objek Worksheet di Workbook.

Anda dapat merujuk ke member dari collection, misalnya, objek Worksheets tunggal, dalam tiga cara.

1. Menggunakan nama worksheet.

 Worksheets("Sales").Range("A1").Value = "Hello"                                             

2. Menggunakan nomor indeks (1 adalah worksheet. pertama dimulai dari kiri).

 Worksheets(1).Range("A1").Value = "Hello"                                                   

3. Menggunakan CodeName.

 Sheet1.Range("A1").Value = "Hello"                                                          

Untuk melihat codename dari lembar kerja, buka Visual Basic Editor. Dalam Project Explorer, nama pertama adalah codename. Nama kedua adalah nama worksheet (Sales).

Catatan: codename tetap sama jika Anda mengubah nama worksheet atau urutan lembar kerja Anda jadi ini adalah cara paling aman untuk referensi worksheet. Klik View, Properties Window untuk mengubah nama sandi worksheet. Ada satu kelemahan, Anda tidak dapat menggunakan nama sandi jika Anda referensi worksheet di workbook yang berbeda.

Properties and Methods

Sekarang mari kita lihat beberapa properties dan methods dari koleksi workbook dan worksheet.

Tempatkan command button pada worksheet Anda dan tambahkan baris kode

1. Tambah method dari koleksi workbook menciptakan workbook baru.

 Workbooks.Add                                                                               

Catatan:  Tambahkan method Worksheets collection menciptakan Worksheets baru.

2. Count Properties menghitung jumlah worksheets di workbook.

 MsgBox Worksheets.Count                                                                     

Hasilnya ketika Anda mengklik command button pada lembar kerja:

Sumber: excel-easy.com

Read More

Belajar Membuat Program Dengan Excel (Visual Basic for Applications) - Pelajaran 1 : Macro

Excel VBA (Visual Basic for Applications) adalah nama dari bahasa pemrograman Excel.

• Buat Macro

Dengan Excel VBA Anda dapat mengotomatisasi tugas-tugas di Excel dengan menulis disebut macro. Dalam bab ini, belajar cara membuat makro sederhana yang akan dilaksanakan setelah mengklik tombol perintah. Pertama, aktifkan tab Developer.

Developer Tab

1. Klik kanan di manapun pada ribbon, dan kemudian klik Customize Ribbon.

2. Di bawah Customize Ribbon, di sisi kanan kotak dialog, pilih Main tabs (jika perlu).

3. Periksa kotak centang Developer.

4. Klik OK.

5. Anda dapat menemukan tab Developer sebelah tab View.

Command Button

Untuk menempatkan tombol perintah pada lembar kerja Anda, jalankan langkah-langkah berikut.

1. Pada tab Developer, klik Insert.

2. Dalam kelompok ActiveX Controls, klik Command Button.

3. Tarik command button pada lembar kerja Anda.

Assign a Macro

Untuk menetapkan macro (satu atau lebih baris kode) ke tombol perintah, jalankan langkah-langkah berikut.

1. Klik kanan CommandButton1 (pastikan Design Mode dipilih).

2. Klik View Code.

Visual Basic Editor muncul.

3. Tempatkan kursor antara Private Sub CommandButton1_Click () dan End Sub.

4. Tambahkan baris kode di bawah ini.

Catatan: jendela di sebelah kiri dengan nama Sheet1, Sheet2 dan Sheet3 disebut Project Explorer. Jika project Explorer tidak terlihat, klik View, Project Explorer. Untuk menambahkan jendela kode untuk lembar pertama, klik Sheet1 (Sheet1).

5. Tutup Visual Basic Editor.

6. Klik command button pada sheet (pastikan Design Mode tidak terpilih pada menu Developer).

hasil:

Selamat. Anda baru saja membuat macro di Excel!

Visual Basic Editor

Untuk membuka Visual Basic Editor, pada Developer tab, klik Visual Basic.

Visual Basic Editor muncul.

Sumber:excel-easy.com

Read More

Visual Basic 2010 Pelajaran 2-Bekerja dengan Controls

Controls dalam Visual Basic 2010 adalah alat yang dapat ditempatkan dalam bentuk untuk melakukan berbagai tugas. Kita bisa menggunakannya untuk membuat semua jenis aplikasi Windows. Gambar di bawah ini menunjukkan Toolbox yang berisi kontrol dari Visual Basic 2010. Mereka dikategorikan ke dalam Common Controls, Containers, Menus, Toolbars, Data, Components, Printings dan Dialogs. Pada saat ini, kita akan fokus pada common controls. Hanya beberapa yang digunakan common controls adalah Button, Label, ComboBox, ListBox, PictureBox, TextBox dan banyak lagi.

Untuk memasukkan Controls ke formulir Anda, Anda hanya perlu untuk drag Controls dari tool box dan meletakkkannya ke dalam formulir. Anda dapat reposisi dan mengubah ukurannya yang Anda inginkan. Mari kita periksa beberapa contoh yang memanfaatkan Button, Label, TextBox, ListBox dan PictureBox. Anda tidak perlu khawatir begitu banyak tentang kode karena saya akan menjelaskan sintaks program karena pelajaran kode akan Anda pelajari di pelajaran selanjutnya.

Bila Anda klik pada tab Toolbox, Common Controls Toolbox akan muncul.

2.1 Membuat Program Pertama Anda

Berikutnya saya akan menunjukkan cara membuat kalkulator sederhana yang menambahkan dua angka menggunakan kontrol TextBox. Dalam program ini, Anda memasukkan dua text boxes, tiga label dan satu button. Dua text boxes untuk memasukkan dua nomor, satu label adalah untuk menampilkan operator penambahan dan label lainnya adalah untuk menampilkan tanda sama dengan. Label terakhir adalah untuk menampilkan jawabannya. Sekarang mengubah label pada button untuk Hitung, kemudian klik pada button dan masukkan kode berikut:

Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click

Dim num1, num2, product As Single

num1 = TextBox1.Text

num2 = TextBox2.Text

product = num1 + num2

Label1.Text = product

End Sub

Ketika Anda menjalankan program dan memasukkan dua nomor, kemudian menekan tombol Hitung untuk menambahkan dua angka.

Sumber: vbtutor.net

Read More

Visual Basic 2010 Pelajaran 1- Pendahuluan

Visual Basic 2010 adalah versi terbaru dari Visual Basic diluncurkan oleh Microsoft pada tahun 2010. VB2010 hampir mirip dengan Visual Basic 2008, tetapi telah menambahkan banyak fitur baru. Seperti Visual Basic 2008, Visual Basic 2010 juga merupakan Bahasa Object-Oriented Programming (OOP), sehingga telah tertangkap dengan bahasa OOP lain seperti C ++, Java, C # dan lain-lain.

Namun, Anda tidak perlu tahu OOP untuk belajar VB2010. Bahkan, jika Anda sudah familiar dengan Visual Basic 6, Anda dapat belajar VB2010 mudah karena sintaks dan antarmuka yang mirip. Visual Basic 2010 Express Edition tersedia gratis untuk di-download dari situs Microsoft. Klik link ini:

http://www.microsoft.com/visualstudio/en-us/products/2010-editions/visual-basic-express

The Integrated Development Environment ketika Anda memulai VB2010 Express ditampilkan dalam diagram di bawah. IDE Start Page terdiri dari beberapa bagian, yaitu:

• Bagian New Project / Open Project.
• Bagian Recent Project yang menunjukkan daftar project yang telah dibuat oleh Anda baru-baru ini.
• Memulai Pane-it memberikan beberapa tips untuk cepat mengembangkan aplikasi Anda.
• Berita Terbaru  section-It menyediakan berita online terbaru tentang Visual Basic 2010 Express, akan mengumumkan rilis baru dan update
• Properties section-let Anda menjelaskan properti dari setiap kontrol

Untuk mulai membuat aplikasi pertama Anda, Anda perlu untuk mengklik pada New Project. Berikut kotak dialog VB2010 New Project akan muncul.

Kotak dialog menawarkan lima jenis Project yang dapat Anda buat. Seperti yang akan kita pelajari untuk membuat Aplikasi windows, kita akan pilih Windows Forms Application.

Di bagian bawah kotak dialog ini, Anda dapat mengubah nama default project WindowsApplication1 dengan nama lain yang Anda suka, untuk contoh beri nama myFirstProgram. Setelah Anda memiliki nama project, klik OK untuk melanjutkan. Berikut IDE Windows akan muncul, hampir mirip dengan Visual Basic 6. Ini terdiri dari formulir kosong, tab toolbox dan properties. Tata letak sedikit berbeda dari VB2008, Toolbox tidak ditampilkan sampai Anda klik pada Toolbox tab. Ketika Anda klik pada tab Toolbox, common controls Toolbox akan muncul.

Sekarang tarik button control ke dalam formulir, dan ubah Text Button1 menjadi OK di jendela properties, kata OK akan muncul pada tombol, seperti yang ditunjukkan di bawah ini:

Sekarang klik pada tombol OK dan jendela kode muncul. Masukkan kode sebagai berikut:

Ketika Anda menjalankan program dan klik pada tombol OK, kotak dialog akan muncul dan menampilkan pesan "WELCOME TO VISUAL BASIC 2010", seperti yang ditunjukkan di bawah ini:

There you are, Anda telah menciptakan program VB2010 pertama Anda.







Sumber: vbtutor.net

Read More